REBOL [
  Title: "Demo 8 - List view with customized row face"
  Short: "Customized Rowface"
  Author: ["Henrik Mikael Kristensen"]
  Copyright: "2006 - HMK Design"
  Filename: %demo08.r
  Version: 0.0.1
  Created: 25-Mar-2006
  Date: 25-Mar-2006
  License: {
    BSD (www.opensource.org/licenses/bsd-license.php)
    Use at your own risk.
  }
  Purpose: {
    List View with customized row face.
    Double-click a row to edit it.
  }
  History: []
  Keywords: [row-face inline-editing sorting header]
]

do http://www.hmkdesign.dk/rebol/list-view/list-view.r

view layout [
  text bold {List view with a customized row face}
  text {Double-click a row to edit it.}
  text {Edit fields automatically adapt to the size and shape of the cells.}
  text {Focus is placed over the cell you double-click.}
  text {Data is resorted, if sorting is used.}
  li: list-view 200x300 with [
    ; ---------- With a customized ROW-FACE the edit fields automatically
    ;            conform to the size and shape of the elements in ROW-FACE

    editable?: true

    data-columns: [movie format duration]
    readonly-columns: [movie duration]

    ; ---------- When using ROW-FACE to create multiple sub-rows per row,
    ;            the header usually looks best when using a single header
    ;            field
    ;            Sorting will happen on the first column given in DATA-COLUMNS

    header-columns: ["Movies"]

    ; ---------- Use LIST-TEXT for cells.
    ;            Note that you need to subtract the width of the scroller
    ;            to match the width of your list

    row-face: [
      across space 0
      list-text 180x20 font-size 14 black bold return
      list-text 90x14 font-size 10 80.80.80
      list-text 90x14 font-size 10 80.80.80 right
    ]
    data: [
      ["Movie Clip 1" "MOV" 1:56:12]
      ["Movie Clip 2" "AVI" 0:48:12]
      ["Movie Clip 3" "MPEG" 1:33:47]
    ]
  ]
]